Delphi Magazine Collection 2001/Delphi Magazine Collection 20001 (2001).iso/DISKS/Issue25/survive/READER1.PAS

Pascal/Delphi Source File | 1997-07-21 | 5.5 KB | 213 lines

unit Reader1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  DB, MyDS, StdCtrls;

type
  PTestRec = ^TTestRec;
  TTestRec = record
      DelFlag: Byte;
      EmpNo: SmallInt;
      FirstName: string[15];
      LastName: string[20];
      HireDate: TDateTime;
      DeptNo: string[3];
      Salary: Double;
    end;

  TForm1 = class(TForm)
    Memo1: TMemo;
    btnTest: TButton;
    btnClose: TButton;
    procedure btnTestClick(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure btnCloseClick(Sender: TObject);
  private
  public
    MyDataSet: TMyDataSet;
    procedure DumpCurrentRec1;
    procedure DumpCurrentRec2;
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

procedure TForm1.DumpCurrentRec1;
var
  RecBuffer: TTestRec;
begin
  if MyDataSet.GetCurrentRecord(@RecBuffer) then
    with RecBuffer do
      Memo1.Lines.Add(Format('%3d %3d %-15s %-20s %10s %3s %11.0m',
                             [MyDataSet.RecNo, EmpNo, FirstName,
                              LastName, DateToStr(HireDate),
                              DeptNo, Salary])
                     );
end;

procedure TForm1.DumpCurrentRec2;
begin
  with MyDataSet do begin
    Memo1.Lines.Add(Format('%3d %3d %-15s %-20s %10s %3s %11.0m',
                           [RecNo,
                            IntToStr(FieldByName('EmpNo').AsInteger),
                            FieldByName('FirstName').AsString,
                            FieldByName('LastName').AsString,
                            DateToStr(FieldByName('HireDate').AsDateTime),
                            FieldByName('DeptNo').AsString,
                            FieldByName('Salary').AsFloat])
                   );
  end;
end;

procedure TForm1.btnTestClick(Sender: TObject);
var
  BookmarkA,
  BookmarkB: TBookmark;
begin
  with MyDataSet do begin
    TableName := 'TEST1.DAT';
    RecordSize := SizeOf(TTestRec);
    Open;
    try
      Memo1.Lines.Add('Active = ' + IntToStr(Ord(Active)));
      Memo1.Lines.Add('RecordCount = ' + IntToStr(RecordCount));
      Memo1.Lines.Add('RecordSize = ' + IntToStr(RecordSize));

      Memo1.Lines.Add('');
      Memo1.Lines.Add('*** Read to EOF forwards ***');
      First;
      while not Eof do begin
        DumpCurrentRec1;
        Next;
      end;

      Memo1.Lines.Add('');
      Memo1.Lines.Add('*** Read to BOF backwards ***');
      Last;
      while not Bof do begin
        DumpCurrentRec1;
        Prior;
      end;

      Memo1.Lines.Add('');
      Memo1.Lines.Add('*** Test MoveBy ***');
      First;
      MoveBy(10);
      DumpCurrentRec1;
      MoveBy(-5);
      DumpCurrentRec1;

      Memo1.Lines.Add('');
      Memo1.Lines.Add('*** Test Bookmarks ***');
      First;
      MoveBy(10);
      Memo1.Lines.Add('Goto this record and bookmark it:');
      DumpCurrentRec1;
      BookmarkA := GetBookmark;
      try
        MoveBy(-5);
        Memo1.Lines.Add('Then move to a different record:');
        DumpCurrentRec1;
        BookmarkB := GetBookmark;
        try
          if BookmarkValid(BookmarkA) then begin
            GotoBookmark(BookmarkA);
            Memo1.Lines.Add('Then return to bookmarked record:');
            DumpCurrentRec1;
          end;

          Memo1.Lines.Add('Compare two different bookmarks (0=same, 1=different): ' +
                          IntToStr(CompareBookmarks(BookmarkA, BookmarkB)));
          Memo1.Lines.Add('Compare two identical bookmarks (0=same, 1=different): ' +
                          IntToStr(CompareBookmarks(BookmarkA, BookmarkA)));
          Memo1.Lines.Add('Compare two nil bookmarks (0=same, 1=different): ' +
                          IntToStr(CompareBookmarks(nil, nil)));
        finally
          FreeBookmark(BookmarkB);
        end;
      finally
        FreeBookmark(BookmarkA);
      end;

      Memo1.Lines.Add('');
      Memo1.Lines.Add('*** Test Insert ***');
      Insert;
      try
        with PTestRec(ActiveBuffer)^ do begin
          EmpNo := 444;
          FirstName := 'NewGuy';
          LastName := 'Inserted';
          HireDate := Date;
          DeptNo := '621';
          Salary := 100000;
        end;
        Post;
      except
        Cancel;
      end;
      Last;
      DumpCurrentRec1;

      Memo1.Lines.Add('');
      Memo1.Lines.Add('*** Test Update ***');
      Last;
      Memo1.Lines.Add('Rec Before Update:');
      DumpCurrentRec1;
      Edit;
      try
        with PTestRec(ActiveBuffer)^ do
          Salary := Salary + 1000;
        Post;
      except
        Cancel;
      end;
      Memo1.Lines.Add('Rec After Update:');
      DumpCurrentRec1;

      Memo1.Lines.Add('');
      Memo1.Lines.Add('*** Test Delete ***');
      First;
      MoveBy(2);
      Memo1.Lines.Add('Current Record Before Delete:');
      DumpCurrentRec1;
      Delete;
      Memo1.Lines.Add('Current Record After Delete:');
      DumpCurrentRec1;
      MoveBy(-1);
      Memo1.Lines.Add('Current Record Before Delete:');
      DumpCurrentRec1;
      Delete;
      Memo1.Lines.Add('Current Record After Delete:');
      DumpCurrentRec1;
    finally
      Close;
    end;
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  MyDataSet := TMyDataSet.Create(Self);
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  MyDataSet.Free;
end;

procedure TForm1.btnCloseClick(Sender: TObject);
begin
  Close;
end;

end.